Ilusiones ópticas de color en movimiento
¡CUIDADO! Las ilusiones de movimiento anómalo pueden provocar malestar o mareos en observadores sensibles. Si empiezas a sentirte mal al ver las imágenes, ¡abandona esta página inmediatamente!
Mientras buscaba otra cosa (como siempre), encontré la página sobre ilusiones ópticas de Akiyoshi Kitaoka. De todas las ilusiones que ilustra este profesor de psicología, me gustaron especialmente las de "movimiento anómalo". Tanto me intrigaron, que decidí intentar replicarlas en POV-Ray y, como no, hacer algunas variaciones.
El efecto solo puede apreciarse en las imágenes a tamaño completo, y solo es apreciable cuando NO se mira fijamente la imagen. Al pie de la página puedes encontrar el resto de variaciones que hice hasta que empecé a marearme (la primera de todas es la réplica de una de las ilusiones de Akiyoshi).
He aqui el código simplificado de una de las variaciones:
global_settings{max_trace_level 8}
#include "colors.inc"
#include "textures.inc"
#include "functions.inc"
// complementary colors
//#declare c1=rgb <.75,0,.25>;
//#declare c2=rgb <.25,.75,0>;
#declare c1=rgb <1,.5,0>;
#declare c2=rgb <0,.5,1>;
// repeating pattern
#declare r_op=seed(630);
#declare xd=1000*rand(r_op);
#declare yd=1000*rand(r_op);
#declare f_pig=function{
pattern{
gradient x
rotate 360*rand(r_op)*z
warp{repeat x flip x}
}
}
#declare p1=
pigment{
function{
f_pig(x+xd,y+yd,0)
}
color_map{
[0.0 rgb 1]
[0.1 rgb 1]
[0.1 c1]
[0.5 c1]
[0.5 rgb 0]
[0.6 rgb 0]
[0.6 c2]
[1.0 c2]
}
}
plane{z,2
texture{
pigment{p1}
finish{Luminous}
scale .125
}
}
// kaleidoscope for the repeating
#declare kd=.2;
plane{y,0 texture{Mirror} translate -kd*y}
plane{y,0 texture{Mirror} translate -kd*y rotate 120*z}
plane{y,0 texture{Mirror} translate -kd*y rotate 240*z}
// square camera
camera{
location <0,0,-1>
direction 1*z
up 1*y right 1*x
}
Bocetos, pruebas e imágenes relacionadas:
